Digital Command Language

Při přihlášení uživatele k systému OpenVMS se provede příkazový skript LOGIN.COM v uživatelově domovském adresáři. Tento skript je možné použít pro nastavení symbolů a logických jmen. Pro obsah skriptu platí standardní pravidla pro příkazové skripty v OpenVMS (mj. každý příkazový řádek musí začínat znakem dolar).

Příkaz HELP poskytuje nápovědu. Je možné mu zadat jako parametry přímo kus příkazového řádku a HELP vypíše nápovědu k dalším parametrům:

 HELP SEARCH
 HELP SEARCH /EXACT

S parametrem /MESSAGE vypisuje HELP nápovědu k názvům chyb:

 HELP /MESSAGE ACCVIO
 HELP /MESSAGE %SYSTEM-F-ACCVIO

Je také možné vypsat nápovědu k číslu chyby (v prvním příkazu je zadáno číslo signálu v desítkové soustavě, ve druhém v šestnáctkové):

 HELP /MESSAGE /STATUS=98954
 HELP /MESSAGE /STATUS=%x1828A

Příkaz BACKUP slouží nejen k archivaci souborů nebo celých disků na pásky, ale umožňuje také vytvářet archivní soubory s příponou .BCK a kopírovat soubory.

Zkopírování celého podstromu:

 BACKUP [ODKUD...] [KAM...]

Pokud se má kopírovat více souborů, oddělují se jejich jména čárkami. Alternativou je vytvořit soubor obsahující jména souborů, které se mají kopírovat (oddělená mezerami nebo konci řádků) a uvést jeho jméno následované parametrem /INPUT_FILES na místě parametru ODKUD. Pokud se má pracovat s archivem (tj. vytvářet archiv nebo číst archiv), je třeba za jeho jménem napsat parametr /SAVE_SET (stačí zkratka /SAV).

Zkopírování podstromu do archivního souboru (tzv. BACKUP save set):

 BACKUP [ODKUD...] soubor /SAV

Obnovení podstromu ze souboru

 BACKUP soubor /SAV kam

Výpis obsahu *.BCK souboru:

 BACKUP subor.BCK /SAV /LIST

Kopírování zamčených souborů

 BACKUP /IGNORE=INTERLOCK soubor;verze kam

Pokud má *.BCK soubor nastavenou špatnou organizaci souboru, při pokusu o jeho zpracování vypisuje systém chybu NOTSAVESET. Organizaci souboru lze opravit příkazem:

 SET FILE /ATTRIB=(RFM:FIX,RAT:NONE,LRL:32256) soubor.BCK

Při archivaci celého stromu adresářů (nebo vybraných souborů ve stromě adresářů) je možné používat na konci cesty tři tečky, které znamenají, že se mají procházet i vnořené adresáře. V tom případě BACKUP do archivů ukládá jména souborů s cestou, ale bez označení disku (resp. bez části před dvojtečkou). Pomocí parametru /SELECT lze vybírat jen některé soubory a pomocí parametru KAM předepisovat, kam se mají rozbalit. Pokud chceme předepsat, že rozbalovaný soubor má vytvořit nejnovější verzi souboru v archivu, je potřeba za jménem souboru napsat středník nebo tečku. Rozbalování vybraných souborů z archivu do oddělených poadaresářů pak může vypadat například takto:

 BACKUP ARCHIV.BCK /SAV /SELECT=[FAKTURY...]2020*.* NOVY_DISK:[FAKTURY.2020...]*.*;
 BACKUP ARCHIV.BCK /SAV /SELECT=[FAKTURY...]2021*.* NOVY_DISK:[FAKTURY.2021...]*.*;

Pro OpenVMS existuje program ZIP pro vytváření .ZIP archivů. Pokud se mají zachovat OpenVMS atributy souborů, které zajistí jejich bezproblémové rozbalení a používání na jiném systému, je nutné používat parametr "-V" (parametr musí být v apostrofech, jinak ho systém vezme jako malé -v):

 ZIP "-V" archiv.ZIP soubor soubor ...
 UNZIP "-V" archiv.ZIP

Starší verze programu ZIP neumí pracovat s adresářovými stromy.

Příkaz DFU nebo MC DFU zpřístupňuje diskové a souborové utility, které zahrnují prohledávání a mazání adresářových stromů, obnovování smazaných souborů, změnu atributů souborů, hledání a obnovování adresářů, hledání souborových aliasů, kontrolu míry fragmentace a defragmentaci souborů, analýzu a opravu struktury systému souborů a analýzu, defragmentaci, zkrácení nebo prodloužení souboru INDEXF.SYS.

Příkaz SHOW DEVICES (lze zkrátit na SH DEV) vypisuje informace o zařízeních. Jako parametr lze použít jméno zařízení nebo jeho začátek, takže např. SHOW DEV D vypíše informace o discích (u disků se vypisuje i jmenovka disku, počet volných bloků, počet transakcí a počet připojení disku). S parametrem /FULL vypisuje podrobnější informace, s parametrem /FILES vypisuje seznam otevřených souborů včetně jména a PID procesu, který soubor používá – podobně jako unixový příkaz lsof.

Pro setřídění řádků v souboru slouží příkaz SORT:

SORT /KEY=(volby) vstup výstup

Parametr KEY má následující syntaxi: /KEY=(POS:<pozice>,SIZE:<delka>,{DECIMAL|CHARACTER},{ASCENDING|DESCENDING})

Symboly mohou být

• lokální – platí pro 1 proces
• globální – platí i pro potomky procesu

Je-li definován lokální i globální symbol se stejným jménem, má lokální přednost.

Globální (zůstanou nastaveny i po opuštění *.COM skriptu, který je nastavil) symboly se nastavují pomocí příkazu

 jméno :== "řetězec"
 jméno == výraz

lokální pomocí

 jméno := "hodnota"
 jméno = výraz

Pokud jsou ve výrazu použity lexikální funkce (F$jméno), je nutné používat == nebo = a ne :== nebo :=.

Za určitých podmínek nemusí být použity uvozovky a mezery kolem symbolu přiřazení nebo rovnítka. Uvozovky zajišťují, že v řetězci nebudou posloupnosti mezer nahrazovány jednou mezerou a malá písmena velkými.

Je-li v nastavení hodnoty symbolu použita hvězdička, lze při použití jméno symbolu zkracovat až na řetězec před hvězdičkou.

Pro zjištění hodnot symbolů slouží příkaz

 SHOW SYMBOL

bez dalšího parametru se doptá na jméno symbolu, s kvantifikátorem /ALL vypíše všechny lokální symboly, s kvantifikátory /ALL/GLOBAL vypíše všechny globální symboly, se jménem symbolu (lze použít i žolíky * pro libovolný řetězec a % pro libovolný znak) vypíše hodnotu nebo hodnoty příslušného symbolu nebo symbolů (lokálních i globálních – jen jedny z nich lze specifikovat pomocí /LOCAL nebo /GLOBAL). Příkaz SHOW SYMBOL musí dostat jméno symbolu napsané velkými písmeny – pokud se napíše bez uvozovek, DCL ho na velké písmena převede; ale pokud se napíše malými písmeny v uvozovkách, tak je problém.

Příklad příkazových aliasů:

 HOME == "SET DEFAULT SYS$LOGIN"
 TP == "TYPE/PAGE"
 DS == "DIRECTORY/SIZE"
 SQ == "SHOW QUOTA"
 LL == "DIR/SIZE/OWNER/PROT"

Rušení symbolů:

 DELETE /SYMBOL jméno
 DELETE /SYMBOL/GLOBAL jméno

Pro zjištění, zda je symbol definován, lze použít funkci F$TYPE, která vrací typ symbolu (STRING, INTEGER) a pro neexistující symbol vrací prázdný řetězec; jméno symbolu musí být v argumentu F$TYPE bez uvozovek:

$ IF F$TYPE(ABC) .EQS. ""
$ THEN
$ WRITE SYS$OUTPUT "Symbol ABC neni definovan"
$ ENDIF

V unixových shellech je nutné vyhodnocení proměnné vyžádat uvedením znaku dolar před jménem proměnné; text bez uvozovek se nechává jak je, pouze se posloupnosti mezer nahradí jednou mezerou.

DCL je na půlce cesty mezi unixovými shelly a programovacími jazyky: jména souborů v normálních příkazech se píšou bez uvozovek, ale v příkazech, které pracují s řetězci, je nutné řetězce uzavírat do uvozovek. Pokud není jméno uzavřeno v uvozovkách, považuje se za jméno symbolu a použije se hodnota symbolu. Uzavřením jména do apostrofů se vyvolá další úroveň vyhodnocení.

Pokud se jméno symbolu napíše do apostrofů, bude se pracovat se symbolem, jehož jméno je hodnotou toho prvního symbolu (čili je to vlastně odkaz na symbol):

ABC = 123
JMENO := "ABC"
WRITE SYS$OUTPUT "JMENO"
WRITE SYS$OUTPUT JMENO
WRITE SYS$OUTPUT 'JMENO'

První WRITE vypíše řetězec JMENO, druhý ABC a třetí 123. Jméno v apostrofech lze použít i na levé straně přiřazovacího příkazu.

Uvnitř uvozovek lze vyhodnotit symbol tak, že se před jeho jméno napíšou dva apostrofy a za něj jeden:

WRITE SYS$OUTPUT "Hodnota symbolu JMENO: ''JMENO'"

Logická jména se definují příkazem

 ASSIGN hodnota jméno

nebo (pozor, pořadí parametrů je obrácené!)

 DEFINE jméno hodnota

Pro zjištění hodnot logických jmen slouží příkaz

 SHOW LOGICAL jméno

který provede rekurzivní vyhodnocení (a ve jménu lze používat žolíky), nebo

 SHOW TRANSLATION jméno

který provede pouze jednoduché vyhodnocení.

Příkaz

 SHOW LOGICAL /ALL

vypíše všechna logická jména včetně informace, ve které tabulce jsou umístěna.

Zrušení logického jména provede příkaz

 DEASSIGN jméno

Pro získání hodnoty logického jména je nutné použít lexikální funkci F$TRNLNM:

 WRITE SYS$OUTPUT F$TRNLNM("jméno")

I jména disků jsou definována pomocí logických jmen. Dokonce je možné do logického jména přiřadit jméno adresáře zakončené tečkou a toto logické jméno používat podobně jako jméno disku.

Umístění domovského adresáře je uloženo v logickém jméně SYS$LOGIN. Ale za posledním jménem adresáře chybí tečka, takže ho nejde používat jako jméno disku.

Význam kláves lze předefinovat pomocí

 DEFINE/KEY/NOLOG PF1 "CLEAR"/TERMINATE
 DEFINE/KEY/NOLOG PF2 "MAIL"/TERMINATE

Podobně jako v Unixu mnoho příkazů v OpenVMS používá standardní výstup pro výpis na obrazovku, standardní chybový výstup pro výpis chyb a standardní vstup pro vstup pro čtení. Zatímco v Unixu se pro tyto účely používají očíslované popisovače 0, 1 a 2, v OpenVMS se používají následující logická jména:

Předefinováním jednoho nebo více těchto logických jmen lze příslušný vstup nebo výstup přesměrovat. Například pro uložení výpisu příkazu DIR do soubor souboru VYPIS.TXT lze použít:

 DEFINE/USER SYS$OUTPUT VYPIS.TXT
 DIR/SIZE/DATE

Novější systémy mají pro přiblížení k unixovému zápisu příkaz PIPE, pomocí kterého lze uvedené dva příkazy zkrátit na:

 PIPE DIR/SIZE/DATE > VYPIS.TXT

Pokud se SYS$OUTPUT a/nebo SYS$ERROR přesměruje na NLA0: nebude se výstup vypisovat ani ukládat do souboru (NLA0: funguje jako unixové /dev/null).

Unixovému příkazu

$ myprog < input.dat > a.lis

odpovídá v OpenVMS

 ASSIGN/USER A.LIS SYS$OUTPUT
 ASSIGN/USER INPUT.DAT SYS$INPUT
 RUN MYPROG

Následující příklad ukazuje, jak napodobit unixové kolony (v koloně ale běží všechny příkazy současně):

Místo unixového

$ prog1 | prog2 | prog3

použít

 DEFINE/user sys$output temp1.txt
 prog1
 DEFINE/user sys$input  temp1.txt
 DEFINE/user sys$output temp2.txt
 prog2
 DEFINE/user sys$input  temp2.txt
 prog3

případně (na novějších systémech s použitím příkazu PIPE)

 PIPE prog1 | prog2 | prog3

Naopak, některým příkazům, které vyžadují uvedení jména souboru, lze dodat jako parametr jedno ze jmen standardních vstupů nebo výstupů – příkladem je už výše uvedení SYS$OUTPUT u příkaz WRITE:

 WRITE SYS$OUTPUT "Text"

nebo použití SYS$INPUT při filtrování výstupu jiného příkazu pomocí SEARCH (unixový příkaz grep prohledává standardní vstup automaticky, pokud je zavolán s jedním parametrem):

 PIPE příkaz | SEARCH SYS$INPUT vzorek

Symbol SYS$INPUT lze použít místo unixových here-dokumentů:

 $ TYPE SYS$INPUT
 prvni radek
 druhy radek
 treti
 $! pokračování skriptu

Jméno souboru SYS$COMMAND slouží ke čtení vstupu z klávesnice od uživatele:

$ READ/END_OF_FILE=návěští/ERROR=návěští/TIME_OUT=sekund/PROMPT="výzva: " -
  SYS$COMMAND proměnná

Pomlčka na konci prvního řádku znamená pokračování příkazu na dalším řádku (pokračovací řádky nezačínají znakem dolar). Tento příkaz vypíše výzvu, a čeká max. zadaný počet sekund na načtení jednoho řádku z klávesnice. Při chybě a při zadání znaku konce souboru skočí na uvedená návěští.

Vstup od uživatele uloží do proměnné zadané posledním parametrem.

Základní příkazovou konstrukcí v DCL je podmíněný příkaz, který má dvě formy. Kratší obsahuje slovo THEN následované příkazem na stejném příkazovém řádku jako IF s podmínkou a neobsahuje ENDIF:

$ IF F$TYPE(ABC) .EQS. "" THEN WRITE SYS$OUTPUT "Symbol ABC neni definovan"

Pokud je THEN na zvláštním řádku, musí být celá konstrukce ukončena řádkem ENDIF:

$ IF F$TYPE(ABC) .EQS. ""
$ THEN
$ WRITE SYS$OUTPUT "Symbol ABC neni definovan"
$ ELSE
$ WRITE SYS$OUTPUT "Symbol ABC je definovan"
$ ENDIF

Pro porovnání čísel je možné používat následující operátory:

Pro porovnávání řetězců:

Pro vytváření cyklů a dalších příkazových konstrukcí je nutné používat příkaz GOTO – viz následující kapitola. Za příkazem GOTO je číslo návěští. Po provedení příkazu GOTO se vykonávání skriptu přenese na řádek začínající znakem $, za kterým je číslo návěští následované znakem dvojtečka. Ve skriptu nesmí být dvě stejná návěští.

Následující fragment kódu slouží ke čtení souboru po jednotlivých řádcích. Příkaz OPEN otevře soubor se zadaným jménem pro čtení. Číslo 1 v příkazech OPEN, READ a CLOSE je popisovač souboru. Příkaz READ přečte jeden řádek ze souboru s popisovačem 1 do zadané proměnné. Pokud není možné přečíst další řádek souboru, protože už byl předchozím příkazem READ načten poslední, provede se skok na návěští zadané jako hodnota kvalifikátoru /END. Podobně je možné zadat návěští, kam se provede skok při chybě čtení ze souboru pomocí kvalifikátoru /ERROR.

$ OPEN /READ 1 jméno_souboru
$NextLine:
$ READ /END=EndRead 1 proměnná
$! Zpracování obsahu řádku uložené v proměnné proměnná
$ GOTO NextLine
$EndRead:
$ CLOSE 1

Příkaz CLOSE soubor zavře.

DCL má dvě metody definování příkazových procedur; primitivnější používá příkaz GOSUB návěští. Řízení se přenese na řádek

 $návěští:

a pokračuje až do provedení příkazu RETURN. Při této metodě nelze používat parametry, takže hodnoty do a z příkazové procedury je nutné přenášet pomocí symbolů.

Při druhé metodě se příkazová procedura definuje pomocí dvojice příkazů SUBROUTINE a ENDSUBROUTINE:

$návěští: SUBROUTINE
$! Příkazy funkce
$ EXIT
$ ENDSUBROUTINE

přičemž pro návrat z příkazové procedury se používá příkaz EXIT. Pro volání se používá příkaz

 $ CALL návěští [parametr [parametr ...] ]

na parametry se uvnitř procedury odkazuje pomocí symbolů P1, P2, ... P9.

Funkce užitečné pro psaní skriptů. Umožňují např. provádět řetězcové operace, číst systémové hodnoty apod. Popis lze získat příkazem

 HELP LEXICALS

Vybrané lexikální funkce:

Druhý parametr lexikální funkce F$EDIT je seznam požadovaných editačních akcí. Jejich jména jsou oddělena čárkami a uzavřena v uvozovkách:

Pozor: nemění části řetězce uzavřené v uvozovkách!

 username = F$EDIT(F$GETJPI(0,"USERNAME"),"TRIM")

Symbol username uzavřený v normálních apostrofech lze pak používat v dalších příkazech.

Jméno aktuálního stroje:

 node = F$GETSYI("NODENAME")

Symbol F$MODE() vrací řetězec INTERACTIVE, když se jedná o interaktivní session (*.COM spuštěný uživatelem buď přímo nebo z jiného *.COM), BATCH pokud se jedná o dávkové spuštění, další možnosti jsou NETWORK a OTHER.

Výraz řetězec1 + řetězec2 vrátí řetězec, který vznikne spojením (zřetězením) řetězců řetězec1 a řetězec2.

Výraz řetězec - podřetězec vrátí řetězec, z něhož je vypuštěn zadaný podřetězec.

Funkce F$STRING(výraz) převede výraz na řetězec.

Funkce F$LENGTH(řetězec) vrací délku řetězce.

Funkce F$LOCATE(substring,string) vrátí pozici podřetězce v řetězci. Je-li podřetězec hned na začátku, vrací 0; není-li obsažen v řetězci, vrací délku řetězce. Proto je nutné porovnávat výsledek s délkou řetězce:

 IF F$LOCATE(":",VARIABLE) .EQ. F$LENGTH(VARIABLE) THEN ...

Následující příkaz uloží do výstup část řetězce za hranatou závorkou z obsahu symbolu jméno:

 výstup = F$EXTRACT(F$LOCATE("]",jméno)+1,F$LENGTH(jméno),jméno)

F$LENGTH(jméno) vrátí délku celého řetězce, který je obsahem symbolu jméno; úplně správně by zde mělo být F$LENGTH(jméno)-(F$LOCATE("]",jméno)+1), ale pokud je zadaná délka větší než kolik znaků zbývá do konce řetězce, vezme se prostě část řetězce od zadané pozice až do konce. Obojí je lepší než používání konstanty 99 uváděné v různých příkladech, které nebude fungovat, pokud do konce řetězce zbývá více než 99 znaků.

Funkce F$ELEMENT(n, delimiter, string) vrací n-tý prvek z řetězce string; prvky jsou vzájemně odděleny řetězci delimiter. Číslování je od nuly!

Více viz:

• https://web.archive.org/web/20160304222204/http://www.djesys.com/freeware/vms/dclprog.ppt
• http://www.classiccmp.org/interex/conference/hpworld2004/presentations04/4038.pdf – kopie výše uvedeného dclprog.ppt

Parametry F$GETJPI:

Význam vybraných parametrů:

Na VAXech byla stránka paměti 512 bytů, na Alphách může být 8, 16, 32 nebo 64 KB. Pagelet je stránka o velikosti 512 na všech architekturách.

Funkce F$FAO("formátovací řetězec", argument, ...) slouží pro formátovaný výpis a funguje podobně jako printf v jazyce C. Formátovací direktivy:

formáty:

Příkaz

write sys$output F$FAO("|!#(#AS)|", 3, 20, "Nazev", "Zkratka", "Popis")

vypíše

|Nazev               Zkratka             Popis               |

Výsledek provedeného příkazu je v symbolu $STATUS. Liché hodnoty jsou OK, sudé znamenají chybu.

$ DEFINE /USER SYS$OUTPUT NLA0:
$ DEFINE /USER SYS$ERROR NLA0:
$ DIR [.ADRES]ABC.TXT
$ IF $STATUS .EQS. "%X1001C04A"
$ THEN
$ WRITE SYS$OUTPUT "Adresar [.ADRES] neexistuje"
$ ENDIF

Na jméně souboru (zde ABC.TXT) nezáleží. Pokud soubor náhodou existuje, pak existuje i adresář a vrátí se status %X00000001, pokud existuje adresář, ale soubor ne, vrátí se status %X10018290. Pokud adresář neexistuje, vrátí se status %X1001C04A.

OpenVMS na rozdíl od Unixových systémů, MS-DOSu a MS-Windows podporuje různé formáty souborů na úrovni systému souborů podobně jako tomu bylo u operačních systémů sálových počítačů v 60. letech 20. století. O zpracování různých formátů souborů se stará vrstva operačního systému nazývaná Record Management Services (RMS). RMS podporuje čtyři přístupové metody k záznamům: sekvenční přístup, přístup podle relativního čísla záznamu, přístup podle adresy záznamu v souboru a indexovaný přístup, a několik formátů záznamů: záznamy pevné délky, záznamy proměnné délky, záznamy proměnné délky s řídicími bloky pevné délky a proudové soubory (záznamy oddělené ukončovacími znaky).

Pokud organizace souboru na disku nesouhlasí s organizací uvedenou v metadatech souboru (když byl například soubor přenesen ze systému, který různé organizace souborů nepodporuje), je možné informace v metadatech upravit:

 SET FILE /ATTRIB=(...)

Hodnoty atributů jsou popsány v tabulce na stránce File Definition Language. Nastavení správné organizace souboru *.BCK je popsáno v části věnované příkazu BACKUP.

Pokud jsou metadata popisující organizaci souboru správná, a je potřeba vytvořit soubor se stejným obsahem, ale jinou organizací, je pro konverzi nutný popis organizace souboru v jazyce File Definition Language. Soubor pak lze zkonvertovat příkazem:

 CONVERT/FDL=organizace.FDL soubor výstup

Nebo lze vytvořit nový soubor s požadovanou organizací příkazem

 CREATE/FDL=organizace.FDL nový_soubor

Soubor *.FDL s popisem požadované organizace výstupního souboru lze získat dvěma způsoby:

• Z existujícího souboru s požadovanou organizací pomocí příkazu ANALYZE/RMS_FILE/FDL
• Pomocí editoru FDL souborů – příkazem EDIT /FDL

Další možností je vytvořit FDL soubor obyčejným textovým editorem.

Následující příkaz načte informace o organizaci zadaného souboru do souboru organizace.FDL:

 ANALYZE/RMS_FILE/FDL/OUTPUT=organizace soubor

Soubor organizace.FDL lze vypsat příkazem TYPE a editovat příkazem

 EDIT /FDL organizace.FDL

Po chvíli se objeví menu, ze kterého je třeba vybrat Modify zadáním M (lze používat celé položky menu nebo jejich jednoznačné zkratky). Objeví se nabídka, jaké primární atributy lze modifikovat, po výběru jednoho z nich jaké sekundární. Po výběru atributu a zadání jeho nové hodnoty lze zadat Ctrl-Z a pak exit. Podrobnosti jsou na stránce File Definition Language.

Podobně jako v MS-DOSu nebo v unixových shellech má DCL interní příkazy: ASSIGN, CALL, DEFINE, GOSUB, GOTO, IF, RETURN, SET, STOP, ...

Pro spuštění skriptu (*.COM) je nutné použít příkaz DO:

 DO USER_DISK:[DIRECTORY.SUBDIR]JMENO

Místo DO je možné použít @:

 @USER_DISK:[DIRECTORY.SUBDIR]JMENO

Podobně pro binární programy (mají příponu .EXE) je nutné použít příkaz RUN:

 RUN USER_DISK:[DIRECTORY.SUBDIR]JMENO

Místo RUN je možné použít $:

 $USER_DISK:[DIRECTORY.SUBDIR]JMENO

Tento způsob spouštění programů a skriptů je těžkopádný a neumožňuje používání parametrů. Lepší způsob je popsán dále.

V novějších verzích OpenVMS používá DCL logické jméno DCL$PATH podobným způsobem jako Unix, MS-DOS nebo MS-Windows proměnnou prostředí PATH – jako seznam jmen adresářů, ve kterých se mají hledat programy (*.EXE a *.COM soubory). DCL$PATH může obsahovat více jmen adresářů oddělených čárkami.

 DIR DCL$PATH:jmeno.*

Standardní způsob definice příkazů je ale použití CLD (Command Language Definition) definic nebo symbolů – tzv. foreign commands.

Pokud má být možné spouštět program SYS$SYSEXE:FOO.EXE příkazem FOO, který může přijímat kvalifikátor "/BAR", je třeba vytvořit CLD soubor obsahující:

DEFINE VERB FOO
   IMAGE "SYS$SYSEXE:FOO.EXE"
   QUALIFIER BAR

soubor se umístí do libovolného adresáře a provede se

 SET COMMAND cesta:FOO.CLD

tím se do tabulky příkazů procesu vloží informace o příkazu FOO. Není známo, zda a jak se tyto informace vypisují.

Foreign commands se definují jako symboly:

 FOO :== "$SYS$SYSEXE:FOO.EXE"

Další informace viz:

• http://www.answers.com/topic/digital-command-language
• https://web.archive.org/web/20120627115440/http://h71000.www7.hp.com/doc/82final/6100/6100pro.html
• http://www.encompassus.org/ftplib/VS0169_VMS94A_TK_KILL_AAAREADME_DOC.html%5B%5D

Zjištění, jestli je přístupný příkaz UNZIP a případně jeho nadefinování:

 $ IF F$SEARCH("DCL$PATH:UNZIP.*") .EQS. "" .AND. F$TYPE(UNZIP) .EQS. ""
 $ THEN
 $   UNZIP == "$TOOLS:UNZIP"
 $ ENDIF

OpenVMS má příkazy SHOW DISPLAY a SET DISPLAY. Příkaz SET DISPLAY umožňuje pomocí kvalifikátorů měnit i jednotlivé složky nastavení beze změny ostatních hodnot:

 SET DISPLAY /SERVER=0

Na stroji, kde není DISPLAY vůbec nastaven, je potřeba pro otevření DECtermu na specifikovaném X-displeji:

$ SET DISPLAY /CREATE /TRANSPORT=TCPIP /NODE=10.224.138.12 /SERVER=0 /SCREEN=0
$ CREATE /TERMINAL /DETACH

Pokud se spustí jako druhý X server třeba Cygwin příkazem

$ startx -- :1 -clipboard

bude nutné použít /SERVER=1

Následující část skriptu LOGIN.COM zajistí nastavení DISPLAY na stroj, ze kterého se uživatel hlásí protokolem telnet (pro ssh není potřeba):

$ define /user sys$output tempshowprocess.txt
$ show process
$ pipe search /nostat tempshowprocess.txt "Host:" | -
  ( read sys$pipe p9 ; DEFINE /JOB P9 &P9)
$ DELETE tempshowprocess.txt;*
$ REMOTE_HOST = F$TRNLNM( "P9" )
$ REMOTE_HOST = f$extract(f$locate("(Host: ", REMOTE_HOST )+7, F$LENGTH(REMOTE_HOST), REMOTE_HOST )
$ REMOTE_HOST = f$extract(0, f$locate(" ", REMOTE_HOST ), REMOTE_HOST )
$ DEASSIGN /JOB P9
$ WRITE SYS$OUTPUT "Opening terminal on the display ''REMOTE_HOST'"
$ set display /create /transport=tcpip /node="''REMOTE_HOST'" /server=0 /screen=0
$ create /terminal /detach

Příkaz SHOW SYSTEM vypíše aktuální seznam procesů a podprocesů. S parametrem /SUBPROCESS vypíše pouze podprocesy, s parametrem /NOSUBPROCESS naopak poprocesy vynechá. S parametry /BATCH, /INTERACTIVE, resp. /NETWORK vypíše pouze dávkové, interaktivní, resp. síťové procesy.

Parametr /OUTPUT=soubor zajistí přesměrování výstupu do souboru, /NOOUTPUT potlačí výstup úplně.

Zatímco Unix spouští programy pomocí fork a následným exec, v OpenVMS se používá pouze exec. Díky tomu po STOP /ID=číslo dojde k zavření terminálu používaného příslušným programem, nikoli k návratu do příkazového řádku. Podproces lze vytvořit příkazem SPAWN a ukončit normálním LOGOUT.

Spuštění DCL skriptu, aby neskončil při odhlášení

 RUN /DETACHED SYS$SYSTEM:LOGINOUT.EXE /INPUT=soubor.COM

V souboru SYS$COMMON:[SYSEXE]SYSUAF.DAT jsou informace o právech uživatelů. Kdo má k tomuto souboru práva, může po spuštění RUN AUTHORIZE zobrazit tato práva příkazem SHOW jméno_uživatele. zpracovává

 MC AUTHORISE
 AUF> SHOW uživatel

vypíše práva uživatele, jeho ID apod.

 WRITE SYS$OUTPUT "OpenVMS ''F$GETSYI("VERSION")' ''F$GETSYI("NODENAME")'   ''F$GETSYI("HW_NAME")'"

Pokud omylem vypíšeme binární soubor na obrazovku, terminál nebo emulátor terminálu se může přepnout do režimu, kdy místo ASCII znaků vypisuje semigrafické znaky (rámečky apod.). Zpětné přepnutí terminálu zajistí spuštění následujícího skriptu, který vypíše řídicí znak Escape následovaným malým c:

$! Reset terminal fonts after displaying binary file
$ ESC[0,8] = 27
$ WRITE SYS$OUTPUT "''ESC'c"

První příkaz zapne na příkazovém řádku režim vkládání a nastaví délku řádku na 170 znaků a výšku okna na 50 textových řádků, další příkazy zajistí poslání escape sekvence, která v prostředí X11 nastaví velikost okna na hodnoty zadané v prvním příkazu:

$ SET TERM/INS/WI=170/PAG=50
$ ESC[0,8] = 27
$ SCREEN_WIDTH = F$GETDVI(F$TRNLNM("TT"),"DEVBUFSIZ")
$ SCREEN_HEIGHT = F$GETDVI(F$TRNLNM("TT"),"TT_PAGE")
$ WRITE SYS$OUTPUT "''ESC'[8;''SCREEN_HEIGHT';''SCREEN_WIDTH't"

Následující skript nastaví titulek v rámu terminálového okna (a titulek u ikony) na řetězec zadaný jako parametr skriptu:

$ esc[0,8] = 27
$ brr[0,8] = 93
$ bsl[0,8] = 92
$
$ If f$trnlnm("DECW$DISPLAY") .eqs. "" Then Exit
$
$ win_title = " ''P1' "
$ if f$length(win_title) .gt. 64
$ Then
$ win_title = f$edit(win_title, "COMPRESS")
$ Endif
$ icn_title = " ''P1' "
$ ln1 = esc + brr + "21;" + win_title + esc + bsl
$ ln1 = ln1 + esc + brr + "2L;" + icn_title + esc + bsl
$ write sys$output ln1
$!
$ Exit